***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Nov 13, 2025                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt MBR8200YD-AU A K
.param
+vc0 = 1.080e-9		vc1 = 2.076e-10		vc2 = 9.850e-1		vc3 = 8.903e-10		vc4 = 8.407e-5
+tc1 = 9.022e-2		tc2 = 5.706e-2		tc3 = 1.102e-1		tc4 = 4.618e-2		   
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter ***
+level = 1   
***** dc model parameter ***
+ is = 9.700e-9	 	  n =1.080		 rs = 7.800e-3		ikf = 7.001e-2
+ibv = 0.5e-3		nbv = 1 		 bv = 220
***** capacitance parameter ***
+cjo = 4.353e-10	  m = 4.525e-1		 vj = 4.421e-1
+ fc = 0.5                      
***** temperature coefficient ***
+tnom = 25		 eg = 8.000e-1  	xti = 3
+trs1 = -2.550e-3      tikf = 1.200e-2         
.ends MBR8200YD-AU
*$
